I'm not sure I understand this part of your questions. The obvious answer is that in the Video Save config for each camera you can select whatever directory you want it to put the video files in. But I don't think that is what you are asking (?)


First select "Time based name" in the Video Save config. This will cause every video file to be given a unique name based on recording start time.

Then use the AbelCam Scheduler to do Add Cam every hour/day/whatever you want. Have it add the same cam to the same cam number (IOW you have it re-add a camera that is already existing and running) This sounds like it would be pointless, but what happens is that it will cause the cam to stop and re-start, which will break the video file like you want.



No easy answer. This capability exists in AbelCam for Local Save files but not for Video Save files. Before AbelCam had this feature I wrote a "shell script" (actually called a WSH VBS Script on Windows) that deletes all jpg files from c:\camstills\ that are more than one day old. I set it up in Windows Task Scheduler to run once a day. It worked fine. I'll paste the script code below - you could probably modify it pretty easily to delete video files from whatever directory you want, with a different number of days, etc.

dtmTargDate = date
dtmTargDate = DateAdd("d", -2, dtmTargDate)

strMonth = Month(dtmTargDate)
If Len(strMonth) = 1 Then
    strMonth = "0" & strMonth
End If

strDay = Day(dtmTargDate)
If Len(strDay) = 1 Then
    strDay = "0" & strDay
End If

strDelDate = Year(dtmTargDate)
strDelDate = strDelDate & strMonth
strDelDate = strDelDate & strDay
strDelDate = strDelDate & "000000.000000-480"

' Uncomment the following line for testing
' Wscript.Echo strDelDate

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colFileList = objWMIService.ExecQuery _
    ("Select * From CIM_DataFile Where " & _
    "CreationDate < '" & strDelDate & "'" & _
    "AND Drive = 'C:' " & _
    "AND Path = '\\camstills\\' " & _
    "AND Extension = 'jpg'")

For Each objFile In colFileList
    objFile.Delete
Next

Okay, maybe clearer like this:

dtmTargDate = date

' The -2 below is minus 2 days. That means we delete
' all files that are 2 or more days old, and keep
' the ones that are <= 1 day old.
' For 5 days use -6, 10 days -11, etc.

dtmTargDate = DateAdd("d", -2, dtmTargDate)

' No need to change the following block of code
' it is just converting the delete date-time to
' a format acceptable for WMI queries.
strMonth = Month(dtmTargDate)
If Len(strMonth) = 1 Then
    strMonth = "0" & strMonth
End If
strDay = Day(dtmTargDate)
If Len(strDay) = 1 Then
    strDay = "0" & strDay
End If
strDelDate = Year(dtmTargDate)
strDelDate = strDelDate & strMonth
strDelDate = strDelDate & strDay
strDelDate = strDelDate & "000000.000000+000"

' Uncomment following line for testing
' Wscript.Echo strDelDate

' Don't change this block
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

' Here you see the Drive (C: ), the Path (\camstills\)
' [but note that you must use double backslashes "\\"]
' and the file type (jpg).
' So this code deletes JPG files from C:\camstills\

Set colFileList = objWMIService.ExecQuery _
    ("Select * From CIM_DataFile Where " & _
    "CreationDate < '" & strDelDate & "'" & _
    "AND Drive = 'C:' " & _
    "AND Path = '\\camstills\\' " & _
    "AND Extension = 'jpg'")

For Each objFile In colFileList

' Uncomment next line to do real deleting
'    objFile.Delete

' Comment out next line when done testing
Wscript.Echo objFile.Name

Next

Save it with .vbs extension. When you type name.vbs on the command line Windows should know to process the .vbs file with the WSH.

The code is set up for "safe" testing - it will not actually delete anything but it will pop up message boxes giving the names of files it would delete. (that is what Wscript.Echo does - 'prints' in a message box). When you are ready for it to delete for real, comment out the line "Wscript.Echo objFile.Name" and uncomment "objFile.Delete"

Also note that it can take a few minutes for it to build the list of files. If it looks like it is not doing anything, check your hard drive LED and you will probably see that it is searching the disk.

I installed "Eraser" to check it out. It's an interesting program but I can not see way to set up "files older than" in its schedule. I think I'll keep it for the secure deletion capabilities for those occasions when I want KGB-style secrecy .

Thank you.

Please also consider a way for implementing rules to break video save files according to time limit (days/months/hours).

This would be easier for the users to do it via rules instead of removing and re-adding the same cameras just to divide a lengthy video recording file.

Thanks again.

Ok please keep the option to create a new video file (with name based on date/time), when the old video file is split based on the time limit or file size as you have mentioned.

Thanks.